Update

subprojects/gstreamer-vaapi/docs/index.md

@@ -0,0 +1,34 @@
+---
+short-description: GStreamer plugins from gstreamer-vaapi
+...
+
+# VAAPI Plugin
+
+## Environment variables
+
+GStreamer-VAAPI inspects a few of environment variables to define it
+usage.
+
+**GST_VAAPI_ALL_DRIVERS.**
+
+This environment variable can be set, independently of its value, to
+disable the drivers white list. By default only intel and mesa va
+drivers are loaded if they are available. The rest are ignored. With
+this environment variable defined, all the available va drivers are
+loaded, even if they are deprecated.
+
+**LIBVA_DRIVER_NAME.**
+
+This environment variable can be set with the drivers name to load. For
+example, intel's driver is `i965`, meanwhile mesa is `gallium`.
+
+**LIBVA_DRIVERS_PATH.**
+
+This environment variable can be set to a colon-separated list of paths
+(or a semicolon-separated list on Windows). libva will scan these paths
+for va drivers.
+
+**GST_VAAPI_DRM_DEVICE.**
+This environment variable can be set to a specified DRM device when DRM
+display is used, it is ignored when other types of displays are used.
+By default /dev/dri/renderD128 is used for DRM display.

subprojects/gstreamer-vaapi/docs/meson.build

@@ -0,0 +1,74 @@
+build_hotdoc = false
+
+if meson.is_cross_build()
+    if get_option('doc').enabled()
+        error('Documentation enabled but building the doc while cross building is not supported yet.')
+    endif
+
+    message('Documentation not built as building it while cross building is not supported yet.')
+    subdir_done()
+endif
+
+required_hotdoc_extensions = ['gi-extension', 'gst-extension']
+if gst_dep.type_name() == 'internal'
+    gst_proj = subproject('gstreamer')
+    plugins_cache_generator = gst_proj.get_variable('plugins_cache_generator')
+else
+    plugins_cache_generator = find_program(join_paths(gst_dep.get_variable('libexecdir'), 'gstreamer-' + api_version, 'gst-plugins-doc-cache-generator'),
+        required: false)
+endif
+
+plugins_cache = join_paths(meson.current_source_dir(), 'gst_plugins_cache.json')
+if plugins_cache_generator.found()
+    plugins_doc_dep = custom_target('vaapi-plugins-doc-cache',
+        command: [plugins_cache_generator, plugins_cache, '@OUTPUT@', '@INPUT@'],
+        input: plugins,
+        output: 'gst_plugins_cache.json',
+        build_always_stale: true,
+    )
+else
+    warning('GStreamer plugin inspector for documentation not found, can\'t update the cache')
+endif
+
+hotdoc_p = find_program('hotdoc', required: get_option('doc'))
+if not hotdoc_p.found()
+    message('Hotdoc not found, not building the documentation')
+    subdir_done()
+endif
+
+hotdoc_req = '>= 0.11.0'
+hotdoc_version = run_command(hotdoc_p, '--version', check: false).stdout()
+if not hotdoc_version.version_compare(hotdoc_req)
+    if get_option('doc').enabled()
+        error('Hotdoc version @0@ not found, got @1@'.format(hotdoc_req, hotdoc_version))
+    else
+        message('Hotdoc version @0@ not found, got @1@'.format(hotdoc_req, hotdoc_version))
+        subdir_done()
+    endif
+endif
+
+build_hotdoc = true
+hotdoc = import('hotdoc')
+if not hotdoc.has_extensions(required_hotdoc_extensions)
+    if get_option('doc').enabled()
+        error('Documentation enabled but gi-extension missing')
+    endif
+
+    message('@0@ extensions not found, not building documentation'.format(required_hotdoc_extensions))
+    subdir_done()
+endif
+
+message('Plugins: @0@'.format(plugins))
+libs_doc = []
+plugins_doc = [hotdoc.generate_doc('vaapi',
+    project_version: api_version,
+    sitemap: 'sitemap.txt',
+    index: 'index.md',
+    gst_index: 'index.md',
+    gst_smart_index: true,
+    gst_c_sources: ['../gst/*/*.[ch]',],
+    gst_cache_file: plugins_cache,
+    gst_plugin_name: 'vaapi',
+    dependencies: [gstbase_dep, gstvideo_dep, gstallocators_dep, gstpbutils_dep,
+    libva_dep, gstlibvaapi_dep, gstgl_dep, libm] + plugins,
+)]

subprojects/gstreamer-vaapi/docs/sitemap.txt

@@ -0,0 +1 @@
+gst-index